|#| constant, @sleep, 60
|#| constant, @line x1, 10
|#| constant, @line y1, 10
|#| constant, @line x2, 30
|#| constant, @line y2, 10
|#| constant, @pixel r, 255 
|#| constant, @pixel g, 255
|#| constant, @pixel b, 255
|#| constant, @pixel r, 87
|#| constant, @pixel g, 87
|#| constant, @pixel b, 87
|#| constant, @pixel r, 219 
|#| constant, @pixel b, 12
|#| constant, clear @pixel r, 255
|#| constant, clear @pixel g, 255
|#| constant, clear @pixel b, 255
|#| constant, clear old mouse x, 1000000
|#| constant, clear old mouse y, 1000000
|#| constant, current mouse x -> old mouse x, 1000000
|#| constant, current mouse y -> old mouse y, 1000000
|#| constant, @mouse x -> current mouse x, 1000000
|#| constant, @mouse y -> current mouse y, 1000000
|#| constant, copy old mouse x -> @line x1, 1000000
|#| constant, copy old mouse y -> @line y1, 1000000
|#| constant, copy current mouse x -> @line x2, 1000000
|#| constant, copy current mouse y -> @line y2, 1000000

|clear pixel color|
    , clear @pixel r:255
    , clear @pixel g:255
    , clear @pixel b:255

|clear @pixel r, @pixel r| |clear @pixel g, @pixel g| |clear @pixel b, @pixel b|
|clear @pixel r| |clear @pixel g| |clear @pixel b|

|clear old mouse x, old mouse x| |clear old mouse x|
|clear old mouse y, old mouse y| |clear old mouse y|

|current mouse x -> old mouse x, current mouse x| old mouse x
|current mouse y -> old mouse y, current mouse y| old mouse y

|current mouse x -> old mouse x| |current mouse y -> old mouse y|

|@mouse x -> current mouse x, @mouse x| current mouse x
|@mouse y -> current mouse y, @mouse y| current mouse y

|@mouse x -> current mouse x| |@mouse y -> current mouse y|

|copy old mouse x -> @line x1, old mouse x| 
    , used old mouse x, @line x1

|copy old mouse y -> @line y1, old mouse y| 
    , used old mouse y, @line y1

|copy current mouse x -> @line x2, current mouse x| 
    , used current mouse x, @line x2

|copy current mouse y -> @line y2, current mouse y|
    , used current mouse y, @line y2

|copy old mouse x -> @line x1| |copy old mouse y -> @line y1|
|copy current mouse x -> @line x2| |copy current mouse y -> @line y2|

|used old mouse x| old mouse x 
|used old mouse y| old mouse y
|used current mouse x| current mouse x
|used current mouse y| current mouse y

|clear old mouse position|
    , clear old mouse x:1000000
    , clear old mouse y:1000000

|move current mouse position to old mouse position|
    , current mouse x -> old mouse x:1000000
    , current mouse y -> old mouse y:1000000

|move @mouse position to current mouse position|
    , @mouse x -> current mouse x:1000000
    , @mouse y -> current mouse y:1000000

|update mouse position|
    , @mouse position
    , clear old mouse position
    , move current mouse position to old mouse position
    , move @mouse position to current mouse position

|check if mouse button 1 is down, find brush mode|
    , @mouse is down
    , @mouse button
    , checking button 1

|check if mouse button 2 is down, find brush mode|
    , @mouse is down
    , @mouse button, @mouse button
    , checking button 2

|check if mouse button 3 is down, find brush mode|
    , @mouse is down
    , @mouse button, @mouse button, @mouse button
    , checking button 3

|checking button 1, @mouse button is down|
    brush is drawing

|checking button 2, @mouse button is down|
    brush is erasing

|checking button 3, @mouse button is down|
    brush is drawing red

|checking button 3| find brush mode
|checking button 2| find brush mode
|checking button 1| find brush mode
|find brush mode|

|check if mouse button is down|
    , find brush mode
    , check if mouse button 1 is down
    , check if mouse button 2 is down
    , check if mouse button 3 is down

|set line color, current color is 1|
    , current color is 1
    , @pixel r:255
    , @pixel g:255
    , @pixel b:255

|set line color, current color is 2|
    , current color is 2
    , @pixel r:87
    , @pixel g:87
    , @pixel b:87

|set line color, current color is 3|
    , current color is 3
    , @pixel r:219
    , @pixel b:12

|set line color, current color is 4|
    current color is 4

|set line position|
    , copy old mouse x -> @line x1:1000000
    , copy old mouse y -> @line y1:1000000
    , copy current mouse x -> @line x2:1000000
    , copy current mouse y -> @line y2:1000000

|draw the line| @draw line

|plot line|
    , set line position
    , draw the line

|draw a line, brush is drawing|
    , clear pixel color
    , set line color
    , plot line

|draw a line, brush is erasing|
    , clear pixel color
    , plot line

|draw a line|

|check for color change|
    , update color
    , @mouse wheel

|update color, @mouse wheel +y| next color

|update color, @mouse wheel -y| previous color

|current color is 1, next color| current color is 2
|current color is 2, next color| current color is 3
|current color is 3, next color| current color is 4
|current color is 4, next color| current color is 1

|current color is 1, previous color| current color is 4
|current color is 2, previous color| current color is 1
|current color is 3, previous color| current color is 2
|current color is 4, previous color| current color is 3

|@mouse wheel +y| |@mouse wheel -y|

|update|
    , update mouse position
    , check if mouse button is down
    , draw a line

|poll inputs| 
    @poll inputs

|draw brush color|
    , set line color
    , @line x1:10, @line x2:30
    , @line y1:10, @line y2:10
    , draw the line

|display|
    @display

|sleep|
    @sleep:16


|main loop|
    , poll inputs
    , check for color change
    , update
    , draw brush color
    , display
    , sleep
    , main loop

|| current color is 1, main loop