|: Default handlers. :|
|:: update|
|:: handle input|
|:: draw|

|:: draw FPS| :@graphics: draw-fps

|:: clear the screen :screen color: $r $g $b?|
    :@graphics: clear-screen $r $g $b
|:: clear the screen|
    :@graphics: clear-screen 0 0 0

|:: display| :@graphics: display

|:: poll for input|
    :@input: poll-input
    :@input: get-mouse-position
    :@input: check-mouse-button 0
    :@input: check-mouse-button 2

|:@input: mouse-button-pressed 0| :left mouse: pressed
|:@input: mouse-button-pressed 1| :middle mouse: pressed
|:@input: mouse-button-pressed 2| :right mouse: pressed
|:@input: mouse-button-released $x|
|:@input: mouse-position $x $y| :mouse position: $x $y

|:@signal: quit| :quit:

|:left mouse: $x|
|:middle mouse: $x|
|:right mouse: $x|
|:mouse position: $x $y|

|:: check if $key is pressed|
    ::check if $key was pressed
|:: check if $key was pressed :@input: key-pressed $key|
    :key pressed: $key
|:: check if $key was pressed :@input: key-released $key|
    :key released: $key
|:: check if $key was pressed?|
    :@input: check-key $key
|:key pressed: $key|
|:key released: $key|

|:: start :screen resolution: $x $y?|
    :@graphics: set-resolution $x $y
    ::main loop

|:: main loop :quit:|
|:: main loop|
    ::poll for input
    ::handle input
    ::update
    ::draw
    ::display
    ::main loop

|::|:: start