|:@math: $x :@math: $op $y| :@math: $op $x $y

|:note: C | :note number: 0
|:note: C#| :note number: 1
|:note: Db| :note number: 1
|:note: D | :note number: 2
|:note: D#| :note number: 3
|:note: Eb| :note number: 3
|:note: E | :note number: 4
|:note: F | :note number: 5
|:note: F#| :note number: 6
|:note: Gb| :note number: 6
|:note: G | :note number: 7
|:note: G#| :note number: 8
|:note: Ab| :note number: 8
|:note: A | :note number: 9
|:note: A#| :note number: 10
|:note: Bb| :note number: 10
|:note: B | :note number: 11
|:note: $x| :note number: $x

|:note number: _|
|:note number: $note :@math: $actual-note|
    :note number: $actual-note
|:note number: $note? :octave: $octave|
    :@math: multiply $octave 12
    :@math: add $note
|:note number: $note? :note basis: $basis|
    :@math: add $note $basis

|:BPM: $x :@math: $n|
    :note delay: $n
|:BPM: $x? :note length: 1 / $y?|
    :@math: divide 60000 $x
    :@math: divide $y

|:: play a note on $channel :note number: $note|
    :: play $note on $channel
|:: play a note on $channel|

|:: play $note on $channel|
    :played notes: $note $channel
    :<: $note
    :: set $note on on $channel
|:: play $note on $channel|
    :played notes: $note $channel
    :<: $note
    :: set $note on on $channel
|:: stop $note on $channel|
    :: set $note off on $channel

|:: set $note $state on $channel :note velocity: $velocity?|
    :@midi: note $state $note $velocity $channel

|:: turn off all played notes? :played notes: $note $channel|
    :: set $note off on $channel
|:: turn off all played notes|

|:: sleep $duration $unit|
    :@time: sleep $duration $unit

|:: using MIDI output $output|
    :@midi: set-output $output

||:channel: 0
|:: play? ::# ::$octave|
    :set octave: $octave
    :<: $octave
    :<: #
|:: play ::; :note delay: $delay?|
    :: sleep $delay milliseconds
    :: turn off all played notes
    :: go to the first channel
    :: play
    :<: ;
|:: play? :: $note :blank note symbol: $note?|
    :<: $note
|:: play :: $note :channel: $channel? :set octave: $octave?|
    :: play a note on $channel :note: $note :octave: $octave
    :: go to the next channel
    :: play
|:: play :loop:?|
    :: replay

|:: replay :<: $note|
    :: replay
    :: $note
|:: replay|
    :: play

|:: go to the next channel :@math: $x|
    :channel: $x
|:: go to the next channel? :channel: $x|
    :@math: add $x 1

|:: go to the first channel :channel: $x|
    :channel: 0

|::|:: using MIDI output 0 :: play :: (
    # 5
    C C _ _ ;
    D _ _ _ ;
    G G _ _ ;
    E _ _ _ ;
    C C _ _ ;
)
:blank note symbol: _
:note velocity: 32
:BPM: 180
:note length: 1 / 2